【VBScript】サクラエディタをより便利に：連続GREP

Grep検索使ってますか？

• テキストエディタ(秀丸エディタやVSCodeなど)
• 統合開発環境(EclipseやVisualStudioなど)

このようなアプリケーションには、基本的に搭載されてますね！

今回はサクラエディタの 『Grep機能の紹介』 と 『ちょっとした不満を解消するツールを紹介！』

この記事の著者

お家大好きSE

soratsm

詳しいプロフィール

プロフィール

都内で働くシステムエンジニア
素早く家に帰るために日々技術を磨いています。
学んだ技術をわかりやすく紹介します！ プロフィール詳細

スポンサーリンク

Contents

1. 便利な機能：Grepによる複数ファイル検索
   1. 更に一歩：【タグジャンプ】でGrep結果⇔該当箇所も簡単移動
   2. 問題点：何度も実行するのが面倒
2. コード：Grepを並列実行＆ファイル出力
   1. 解説
3. 使い方
   1. 入力ファイルを作る
   2. 入力ファイルをツールにドラッグ＆ドロップ
   3. 入力ファイルと同じ場所にGrep結果が出力
4. 最後に

便利な機能：Grepによる複数ファイル検索

サクラエディタを開いて『Ctrl + G』を押しましょう。
すると下のよう画面が開きます。

この中の『検索キーワード』『対象ファイルの条件』『検索対象のフォルダ』を入力します。

'★★設定項目　開始★★
'ココは自分のパソコンのexeファイルが場所に書き換える
'フォルダ名が半角スペース入っている場合は、『""xx xx""』とする。
Const SakuraPath = "C:\""Program Files""\sakura\sakura.exe"
'★★設定項目　終了★★

Call JudgeDDFile

'ドラッグ＆ドロップされたファイルの判定
Sub JudgeDDFile()
    Dim objArgs , objFSO , objFiles , ddFile
    Set objArgs = WScript.Arguments
    Set objFSO = CreateObject("Scripting.FileSystemObject")

    'ファイル数判定
    Select Case objArgs.Count
        Case 0
            MsgBox "Grep対象をD&Dしてください"
        Case 1
            ddFile = WScript.Arguments(0)
            Set objFiles = objFSO.GetFile(ddFile)

            'ファイル拡張子判定
            If objFSO.GetExtensionName(ddFile) = "txt" then
                vret = MsgBox("このtxtファイル（" & objFiles.name & "）を基にGrepを実行しますか？",vbokcancel)
                If vret = vbok then
                    '連続Grep処理
                    Call MultiGrep(objFiles)  
                Else
                    MsgBox "中止しました"
                End If
            Else
                MsgBox "ドロップしたファイルは（" & objFiles.name & "）",,"txtファイルをD&Dして下さい"
            End If

            Set objFiles = Nothing
        Case Else
            MsgBox "1ファイルのみD&Dして下さい"
    End Select

    Set objArgs = Nothing   
    Set objFSO = Nothing   
    WScript.Quit
End Sub

'連続Grep処理
Sub MultiGrep(objFiles)
    Dim fso , tso , flds , i
    Dim stringNow , inputPath
    rowNo = 0

    Set fso = CreateObject("Scripting.FileSystemObject")
    '読み取り専用で開く
    Set tso = fso.OpenTextFile(objFiles, 1)

    'ファイル名をユニークにする為、年月日日時取得
    stringNow = GetNow

    '入力ファイルと同じ階層に出力する為に、入力ファイルのパスを取得
    inputPath = fso.getParentFolderName(objFiles)
    
    '入力ファイルの行数分ループ
    While tso.AtEndOfStream <> true
        flds = Split(tso.ReadLine, vbTab)
        rowNo = rowNo + 1
        '"-GKEY【タブ】-GFILE【タブ】-GFOLDER"の形式
        If UBound(flds) = 2 Then
            Call RunGrepCmd(flds , inputPath , rowNo , stringNow)
        End If
    Wend
    tso.Close
    Set fso = Nothing
End Sub

'サクラエディタのGrepコマンドを実行
Sub RunGrepCmd(flds , inputPath , rowNo , stringNow)
    Dim rowNo2 , grepCmd , objShell

    '桁数を揃えるために行番号を2桁に揃える
    If rowNo < 10 Then
        rowNo2 = "0" & rowNo
    Else
        rowNo2 = rowNo
    End If

    'コマンドラインに流す為、Grepコマンドを生成
    grepCmd = "cmd /c " & SakuraPath & " -GREPMODE -GKEY=""" 
    grepCmd = grepCmd & flds(0)
    grepCmd = grepCmd & """ -GFILE="""
    grepCmd = grepCmd & flds(1)
    grepCmd = grepCmd & """ -GFOLDER="""
    grepCmd = grepCmd & flds(2)
    grepCmd = grepCmd & """ -GOPT:""SRPU"" > "
    grepCmd = grepCmd & inputPath & "\Grep結果" & stringNow & "_row" & rowNo2 & ".txt"

    'コマンド実行
    Set objShell = CreateObject("WScript.Shell")
    objShell.Run grepCmd,0,false
    Set objShell = Nothing
End Sub

'年月日日時を取得
Function GetNow()
    Dim w_Now
    Dim w_Month
    Dim w_Day

    '年取得
    w_Now = ""
    w_Now = Year(Now())

    '月取得（二桁で揃える）
    w_Month = Month(Now())
    If w_Month < 10 Then
        w_Now = w_Now & "0" & w_Month
    Else
        w_Now = w_Now & w_Month
    End If

    '日取得（二桁で揃える）
    w_Day = Day(Now())
    If w_Day < 10 Then
        w_Now = w_Now & "0" & w_Day
    Else
        w_Now = w_Now & w_Day
    End If

    '時分秒取得
    w_Now = w_Now & Right("0" & Hour(Now()) , 2)
    w_Now = w_Now & Right("0" & Minute(Now()) , 2)
    w_Now = w_Now & Right("0" & Second(Now()) , 2)

    getNow = w_Now
End Function

ページが見つかりませんでした - イエスキ

家好きSEの技術雑記

www.yeskey.org

cmd /c C:\"Program Files"\sakura\sakura.exe -GREPMODE -GKEY="【キーワード】" -GFILE="【対象ファイル】" -GFOLDER="【対象フォルダ】" -GOPT:"SRPU" > 【入力ファイルのパス】\Grep結果【実行年月日日時】_row【入力ファイルの何行目】.txt

\d{6}	*.txt	D:\Shortcut  
ワード	*.*	D:\GoogleDrive

この楽しさも含めて知ってもらえたら、より嬉しく思います！

【VBScript】ファイルのドラッグ＆ドロップで起動【D&D】

入力したい項目が複数ある場合やファイルの拡張子によって処理切り替えたい場合など、ドラッグ＆ドロップ（D&D）に対応するやり方を覚えておくと、ツールの幅が広がります！

www.yeskey.org

【VBScript】現在日時取得【Now】+α

現在日時をファイル名でも使用できる形(yyyymmddhhmmss)で、取得する方法紹介します。

www.yeskey.org